--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/app/build.gradle	Thu Nov 08 11:39:13 2018 -0800
@@ -0,0 +1,89 @@
+task copyDebugLibTask(type: Copy) {
+    from 'build/intermediates/binaries/debug/arm/lib/armeabi'
+    into 'src/main/jniLibs/armeabi'
+}
+task copyReleaseLibTask(type: Copy) {
+    from 'build/intermediates/binaries/release/arm/lib/armeabi'
+    into 'src/main/jniLibs/armeabi'
+}
+
+tasks.whenTaskAdded { task ->
+    if (task.name.contains("merge") && task.name.contains("JniLibFolders")) {
+        if (task.name.contains("ArmDebug")) {
+            task.dependsOn copyDebugLibTask
+        }
+        if (task.name.contains("ArmRelease")) {
+            task.dependsOn copyReleaseLibTask
+        }
+    }
+}
+
+
+apply plugin: 'com.android.application'
+
+android {
+    signingConfigs {
+        release {
+            print "\nNo Console\n"
+            def read = System.in.newReader().&readLine
+            print "\nkey store password"
+            storePassword = read()
+            print "\nkey alias password"
+            keyPassword   = read()
+            print "\nDone\n"
+            storeFile = file("../510Connectbot.keystore")
+            storeType = "jks"
+            keyAlias  = "510Connectbot"
+        }
+    }
+    compileSdkVersion = 16
+    buildTypes {
+        release {
+            minifyEnabled = false
+            signingConfig = signingConfigs.release
+            ndk {
+                debuggable = false
+                abiFilters 'armeabi-v7a'
+            }
+        }
+        debug {
+            debuggable = true
+            ndk {
+                debuggable = true
+                abiFilters 'armeabi-v7a'
+            }
+        }
+    }
+    flavorDimensions "arch"
+    productFlavors {
+        arm {
+            dimension "arch"
+        }
+        x86 {
+            dimension "arch"
+        }
+    }
+    sourceSets {
+        main {
+            jni {
+                srcDir "Exec"
+            }
+        }
+    }
+
+    defaultConfig {
+        applicationId = "com.five_ten_sg.connectbot"
+        minSdkVersion = 8
+        targetSdkVersion = 15
+        ndk {
+            moduleName = "com_google_ase_Exec"
+        }
+    }
+
+    externalNativeBuild {
+        ndkBuild {
+            path "src/main/jni/Android.mk"
+        }
+    }
+
+}