
AC_PREREQ(2.59)
AC_INIT(dnsbl,6.25,carl@five-ten-sg.com)
AC_CONFIG_SRCDIR([config.h.in])
AC_CONFIG_HEADER([config.h])

AM_INIT_AUTOMAKE($PACKAGE_NAME,$PACKAGE_VERSION)

# Checks for programs.
AC_PATH_PROG(BASH, bash)
if test "x$BASH" = x ; then
    AC_MSG_ERROR([bash required for init script])
fi
AC_PATH_PROG(SPAMC, spamc)
if test "x$SPAMC" = x ; then
    AC_MSG_WARN([spamc not found.  SpamAssassin filtering disabled])
fi
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_LIBTOOL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

# Checks for header files.
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([arpa/inet.h fcntl.h netdb.h netinet/in.h regex.h sys/ioctl.h sys/socket.h syslog.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_ERROR_AT_LINE
AC_FUNC_FORK
AC_FUNC_GETPGRP
AC_HEADER_STDC
AC_FUNC_STAT
AC_FUNC_STRFTIME
AC_CHECK_FUNCS([daemon dup2 gethostbyname gethostname memmove memrchr memset regcomp socket strcasecmp strchr strdup strerror strncasecmp strrchr strstr strtol])

AC_CHECK_FUNCS(regexec,,[AC_CHECK_LIB(regex,regexec,
               [REGEXLIB=-lregex
                AC_DEFINE(HAVE_REGEXEC,1,[Define to 1 if you have the regexec function.])],
               [AC_MSG_ERROR([No regex library found])])])
AC_SUBST(REGEXLIB)

# check for posix threads
ACX_PTHREAD

# See if we have progress callback
AC_CHECK_LIB([milter],
             [smfi_progress],
             [AC_DEFINE(_FFR_SMFI_PROGRESS, 1, Define to 1 to enable progress callback)],
             [AC_DEFINE(_FFR_SMFI_PROGRESS, 0, Define to 1 to enable progress callback)],
    	     [-lpthread]
             )

AC_CONFIG_FILES([Makefile
                 dnsbl.rc
                 dnsbl.spec
                 html/Makefile
                 info/Makefile
                 man/Makefile
                 src/Makefile
                 src/spamass.cpp
                 xml/Makefile
                 xml/dnsbl])
AC_OUTPUT
