Mercurial > syslog2iptables

comparison m4/acx_pthread.m4 @ 44:9e9f09cf411c

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Add fixes for Solaris from sm-archive.
author Carl Byington <carl@five-ten-sg.com>
date Sat, 22 Mar 2008 10:58:24 -0700
parents
children
comparison
equal deleted inserted replaced
43:f7e118192ee6 44:9e9f09cf411c
1 ##### http://autoconf-archive.cryp.to/acx_pthread.html
2 #
3 # SYNOPSIS
4 #
5 # ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
6 #
7 # DESCRIPTION
8 #
9 # This macro figures out how to build C programs using POSIX threads.
10 # It sets the PTHREAD_LIBS output variable to the threads library and
11 # linker flags, and the PTHREAD_CFLAGS output variable to any special
12 # C compiler flags that are needed. (The user can also force certain
13 # compiler flags/libs to be tested by setting these environment
14 # variables.)
15 #
16 # Also sets PTHREAD_CC to any special C compiler that is needed for
17 # multi-threaded programs (defaults to the value of CC otherwise).
18 # (This is necessary on AIX to use the special cc_r compiler alias.)
19 #
20 # NOTE: You are assumed to not only compile your program with these
21 # flags, but also link it with them as well. e.g. you should link
22 # with $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS
23 # $LIBS
24 #
25 # If you are only building threads programs, you may wish to use
26 # these variables in your default LIBS, CFLAGS, and CC:
27 #
28 # LIBS="$PTHREAD_LIBS $LIBS"
29 # CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
30 # CC="$PTHREAD_CC"
31 #
32 # In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
33 # constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
34 # that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
35 #
36 # ACTION-IF-FOUND is a list of shell commands to run if a threads
37 # library is found, and ACTION-IF-NOT-FOUND is a list of commands to
38 # run it if it is not found. If ACTION-IF-FOUND is not specified, the
39 # default action will define HAVE_PTHREAD.
40 #
41 # Please let the authors know if this macro fails on any platform, or
42 # if you have any other suggestions or comments. This macro was based
43 # on work by SGJ on autoconf scripts for FFTW (http://www.fftw.org/)
44 # (with help from M. Frigo), as well as ac_pthread and hb_pthread
45 # macros posted by Alejandro Forero Cuervo to the autoconf macro
46 # repository. We are also grateful for the helpful feedback of
47 # numerous users.
48 #
49 # LAST MODIFICATION
50 #
51 # 2006-05-29
52 #
53 # COPYLEFT
54 #
55 # Copyright (c) 2006 Steven G. Johnson <stevenj@alum.mit.edu>
56 #
57 # This program is free software; you can redistribute it and/or
58 # modify it under the terms of the GNU General Public License as
59 # published by the Free Software Foundation; either version 2 of the
60 # License, or (at your option) any later version.
61 #
62 # This program is distributed in the hope that it will be useful, but
63 # WITHOUT ANY WARRANTY; without even the implied warranty of
64 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
65 # General Public License for more details.
66 #
67 # You should have received a copy of the GNU General Public License
68 # along with this program; if not, write to the Free Software
69 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
70 # 02111-1307, USA.
71 #
72 # As a special exception, the respective Autoconf Macro's copyright
73 # owner gives unlimited permission to copy, distribute and modify the
74 # configure scripts that are the output of Autoconf when processing
75 # the Macro. You need not follow the terms of the GNU General Public
76 # License when using or distributing such scripts, even though
77 # portions of the text of the Macro appear in them. The GNU General
78 # Public License (GPL) does govern all other use of the material that
79 # constitutes the Autoconf Macro.
80 #
81 # This special exception to the GPL applies to versions of the
82 # Autoconf Macro released by the Autoconf Macro Archive. When you
83 # make and distribute a modified version of the Autoconf Macro, you
84 # may extend this special exception to the GPL to apply to your
85 # modified version as well.
86
87 AC_DEFUN([ACX_PTHREAD], [
88 AC_REQUIRE([AC_CANONICAL_HOST])
89 AC_LANG_SAVE
90 AC_LANG_C
91 acx_pthread_ok=no
92
93 # We used to check for pthread.h first, but this fails if pthread.h
94 # requires special compiler flags (e.g. on True64 or Sequent).
95 # It gets checked for in the link test anyway.
96
97 # First of all, check if the user has set any of the PTHREAD_LIBS,
98 # etcetera environment variables, and if threads linking works using
99 # them:
100 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
101 save_CFLAGS="$CFLAGS"
102 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
103 save_LIBS="$LIBS"
104 LIBS="$PTHREAD_LIBS $LIBS"
105 AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
106 AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
107 AC_MSG_RESULT($acx_pthread_ok)
108 if test x"$acx_pthread_ok" = xno; then
109 PTHREAD_LIBS=""
110 PTHREAD_CFLAGS=""
111 fi
112 LIBS="$save_LIBS"
113 CFLAGS="$save_CFLAGS"
114 fi
115
116 # We must check for the threads library under a number of different
117 # names; the ordering is very important because some systems
118 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
119 # libraries is broken (non-POSIX).
120
121 # Create a list of thread flags to try. Items starting with a "-" are
122 # C compiler flags, and other items are library names, except for "none"
123 # which indicates that we try without any flags at all, and "pthread-config"
124 # which is a program returning the flags for the Pth emulation library.
125
126 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
127
128 # The ordering *is* (sometimes) important. Some notes on the
129 # individual items follow:
130
131 # pthreads: AIX (must check this before -lpthread)
132 # none: in case threads are in libc; should be tried before -Kthread and
133 # other compiler flags to prevent continual compiler warnings
134 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
135 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
136 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
137 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
138 # -pthreads: Solaris/gcc
139 # -mthreads: Mingw32/gcc, Lynx/gcc
140 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
141 # doesn't hurt to check since this sometimes defines pthreads too;
142 # also defines -D_REENTRANT)
143 # ... -mt is also the pthreads flag for HP/aCC
144 # pthread: Linux, etcetera
145 # --thread-safe: KAI C++
146 # pthread-config: use pthread-config program (for GNU Pth library)
147
148 case "${host_cpu}-${host_os}" in
149 *solaris*)
150
151 # On Solaris (at least, for some versions), libc contains stubbed
152 # (non-functional) versions of the pthreads routines, so link-based
153 # tests will erroneously succeed. (We need to link with -pthreads/-mt/
154 # -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
155 # a function called by this macro, so we could check for that, but
156 # who knows whether they'll stub that too in a future libc.) So,
157 # we'll just look for -pthreads and -lpthread first:
158
159 acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
160 ;;
161 esac
162
163 if test x"$acx_pthread_ok" = xno; then
164 for flag in $acx_pthread_flags; do
165
166 case $flag in
167 none)
168 AC_MSG_CHECKING([whether pthreads work without any flags])
169 ;;
170
171 -*)
172 AC_MSG_CHECKING([whether pthreads work with $flag])
173 PTHREAD_CFLAGS="$flag"
174 ;;
175
176 pthread-config)
177 AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
178 if test x"$acx_pthread_config" = xno; then continue; fi
179 PTHREAD_CFLAGS="`pthread-config --cflags`"
180 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
181 ;;
182
183 *)
184 AC_MSG_CHECKING([for the pthreads library -l$flag])
185 PTHREAD_LIBS="-l$flag"
186 ;;
187 esac
188
189 save_LIBS="$LIBS"
190 save_CFLAGS="$CFLAGS"
191 LIBS="$PTHREAD_LIBS $LIBS"
192 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
193
194 # Check for various functions. We must include pthread.h,
195 # since some functions may be macros. (On the Sequent, we
196 # need a special flag -Kthread to make this header compile.)
197 # We check for pthread_join because it is in -lpthread on IRIX
198 # while pthread_create is in libc. We check for pthread_attr_init
199 # due to DEC craziness with -lpthreads. We check for
200 # pthread_cleanup_push because it is one of the few pthread
201 # functions on Solaris that doesn't have a non-functional libc stub.
202 # We try pthread_create on general principles.
203 AC_TRY_LINK([#include <pthread.h>],
204 [pthread_t th; pthread_join(th, 0);
205 pthread_attr_init(0); pthread_cleanup_push(0, 0);
206 pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
207 [acx_pthread_ok=yes])
208
209 LIBS="$save_LIBS"
210 CFLAGS="$save_CFLAGS"
211
212 AC_MSG_RESULT($acx_pthread_ok)
213 if test "x$acx_pthread_ok" = xyes; then
214 break;
215 fi
216
217 PTHREAD_LIBS=""
218 PTHREAD_CFLAGS=""
219 done
220 fi
221
222 # Various other checks:
223 if test "x$acx_pthread_ok" = xyes; then
224 save_LIBS="$LIBS"
225 LIBS="$PTHREAD_LIBS $LIBS"
226 save_CFLAGS="$CFLAGS"
227 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
228
229 # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
230 AC_MSG_CHECKING([for joinable pthread attribute])
231 attr_name=unknown
232 for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
233 AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
234 [attr_name=$attr; break])
235 done
236 AC_MSG_RESULT($attr_name)
237 if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
238 AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
239 [Define to necessary symbol if this constant
240 uses a non-standard name on your system.])
241 fi
242
243 AC_MSG_CHECKING([if more special flags are required for pthreads])
244 flag=no
245 case "${host_cpu}-${host_os}" in
246 *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
247 *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
248 esac
249 AC_MSG_RESULT(${flag})
250 if test "x$flag" != xno; then
251 PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
252 fi
253
254 LIBS="$save_LIBS"
255 CFLAGS="$save_CFLAGS"
256
257 # More AIX lossage: must compile with xlc_r or cc_r
258 if test x"$GCC" != xyes; then
259 AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
260 else
261 PTHREAD_CC=$CC
262 fi
263 else
264 PTHREAD_CC="$CC"
265 fi
266
267 AC_SUBST(PTHREAD_LIBS)
268 AC_SUBST(PTHREAD_CFLAGS)
269 AC_SUBST(PTHREAD_CC)
270
271 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
272 if test x"$acx_pthread_ok" = xyes; then
273 ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
274 :
275 else
276 acx_pthread_ok=no
277 $2
278 fi
279 AC_LANG_RESTORE
280 ])dnl ACX_PTHREAD